В режиме «Конфигуратор»

В отличие от документа ПриходнаяНакладная, который создавал всего одну бухгалтерскую проводку, документ ОказаниеУслуги будет создавать уже две.

Напомним, что бухгалтерия нашего ООО «На все руки мастер» не совсем похожа на настоящую, потому что для облегчения своей работы она учитывает только движения материалов. Услуги, которые оказывает организация, для нее как бы не существуют.

Поэтому документ ОказаниеУслуги будет формировать движения по регистру бухгалтерии только в той части, которая касается расходования материалов.

В окне редактирования объекта конфигурации Документ ОказаниеУслуги перейдем на закладку Движения. В списке регистров отметим, что документ будет создавать теперь движения и по регистру Управленческий. Перейдем на закладку Прочее и откроем модуль объекта. Откроем процедуру обработчика события ОбработкаПроведения.

Поскольку нас интересует только движение материалов, для внесения дополнений подойдет тело условия Если…, в котором мы формировали движения по регистрам ОстаткиМатериалов и СтоимостьМатериалов.

Добавим в конец условия, перед строкой КонецЕсли, движения по регистру бухгалтерии Управленческий (листинг 16.3).

Листинг 16.3. Движения документа «ОказаниеУслуги» (фрагмент)

…

Если ВыборкаДетальныеЗаписи.ВидНоменклатуры = Перечисления.ВидыНоменклатуры.Материал Тогда

 

// Регистр ОстаткиМатериалов Расход

…

 

// Регистр СтоимостьМатериалов Расход

…

 

// Регистр Управленческий

// Первая проводка: Д 62(ДебиторскаяЗадолженность) — К 90 (Капитал) Розничная сумма

Движение = Движения.Управленческий.Добавить();

Движение.СчетДт = ПланыСчетов.Основной.ДебиторскаяЗадолженность;

Движение.СчетКт = ПланыСчетов.Основной.Капитал;

Движение.Период = Дата;

Движение.Сумма = ВыборкаДетальныеЗаписи.СуммаВДокументе;

Движение.СубконтоДт[ПланыВидовХарактеристик.ВидыСубконто.Клиенты] = Клиент;

// Вторая проводка: Д 90 (Капитал) — К 41 (Товары) — себестоимость

Движение = Движения.Управленческий.Добавить();

Движение.СчетДт = ПланыСчетов.Основной.Капитал;

Движение.СчетКт = ПланыСчетов.Основной.Товары;

Движение.Период = Дата;

Движение.Сумма = СтоимостьМатериала * ВыборкаДетальныеЗаписи.КоличествоВДокументе;

Движение.КоличествоКт = ВыборкаДетальныеЗаписи.КоличествоВДокументе;

Движение.СубконтоКт[ПланыВидовХарактеристик.ВидыСубконто.Материалы] = ВыборкаДетальныеЗаписи.Номенклатура;

 

КонецЕсли;

…

В первой проводке мы указываем розничную сумму материала из документа и субконто дебета, поскольку на счете Дебиторская задолженность ведется учет в разрезе клиентов.

Во второй проводке мы указываем стоимость материала, количество и субконто кредита, поскольку на счете Товары ведется количественный учет в разрезе материалов.

Теперь в самом начале процедуры установим свойство Записывать регистра бухгалтерии в значение Истина для записи изменений регистров в базу данных (листинг 16.4).

Листинг 16.4. Запись движений регистров

Процедура ОбработкаПроведения(Отказ, Режим)

 

Движения.ОстаткиМатериалов.Записывать = Истина;

Движения.СтоимостьМатериалов.Записывать = Истина;

Движения.Продажи.Записывать = Истина;

Движения.Управленческий.Записывать = Истина;

…

В заключение отредактируем командный интерфейс формы документа, чтобы в панели навигации формы иметь возможность переходить к списку записей регистра Управленческий, связанному с документом. Для этого откроем форму документа ОказаниеУслуги. В левом верхнем окне перейдем на закладку Командный интерфейс. В разделе Панель навигации раскроем группу Перейти и установим видимость для команды открытия регистра бухгалтерии Управленческий.