Документ «Оказание услуги»

Теперь аналогичным образом доработайте документ ОказаниеУслуги.

Для того чтобы при расходовании материалов пользователь мог указывать набор свойств для каждого расходуемого материала, создайте новый реквизит табличной части документа с именем НаборСвойств типа СправочникСсылка.ВариантыНоменклатуры.

У этого реквизита заполните свойство Связи параметров выбора так, чтобы при выборе в поле НаборСвойств открывался список элементов справочника Варианты номенклатуры, подчиненных материалу, выбранному в колонке Номенклатура (отбор по владельцу – ПереченьНоменклатуры.Номенклатура).

После этого расположите этот реквизит в табличной части формы документа. Поместите новый элемент формы в структуре элементов формы после поля Номенклатура.

Теперь откройте модуль документа ОказаниеУслуги.

В процедуре обработчика события ОбработкаПроведения добавьте к формируемым движениям присвоение значения измерению НаборСвойств регистра ОстаткиМатериалов (листинг 16.4).

Листинг 16.4. Фрагмент процедуры «ОбработкаПроведения()»

…

// регистр ОстаткиМатериалов Расход

…

Движение.Материал = ВыборкаДетальныеЗаписи.Номенклатура;

Движение.НаборСвойств = ВыборкаДетальныеЗаписи.НаборСвойств;

Движение.Склад = Склад;

…

Поскольку на предыдущем занятии вы оптимизировали процедуру проведения документа, чтобы все данные документа получались с помощью запроса, в текст запроса нужно также добавить строки для получения нового реквизита документа (листинг 16.5).

Листинг 16.5. Фрагмент процедуры «ОбработкаПроведения()»

…

Запрос = Новый Запрос;

 

// Укажем, какой менеджер временных таблиц использует этот запрос

Запрос.МенеджерВременныхТаблиц = МенеджерВТ;

 

Запрос.Текст =

"ВЫБРАТЬ

|    ОказаниеУслугиПереченьНоменклатуры.Номенклатура,

|    ОказаниеУслугиПереченьНоменклатуры.Номенклатура.ВидНоменклатуры КАК ВидНоменклатуры,

|    ОказаниеУслугиПереченьНоменклатуры.НаборСвойств КАК НаборСвойств,

|    СУММА(ОказаниеУслугиПереченьНоменклатуры.Количество) КАК КоличествоВДокументе,

|    СУММА(ОказаниеУслугиПереченьНоменклатуры.Сумма) КАК СуммаВДокументе

|ПОМЕСТИТЬ НоменклатураДокумента

|ИЗ

|    Документ.ОказаниеУслуги.ПереченьНоменклатуры КАК ОказаниеУслугиПереченьНоменклатуры

|ГДЕ

|    ОказаниеУслугиПереченьНоменклатуры.Ссылка = &Ссылка

|СГРУППИРОВАТЬ ПО

|    ОказаниеУслугиПереченьНоменклатуры.Номенклатура,

|    ОказаниеУслугиПереченьНоменклатуры.Номенклатура.ВидНоменклатуры,

|    ОказаниеУслугиПереченьНоменклатуры.НаборСвойств";

...

Запрос2 = Новый Запрос;

Запрос2.МенеджерВременныхТаблиц = МенеджерВТ;

Запрос2.Текст = "ВЫБРАТЬ

|    НоменклатураДокумента.Номенклатура,

|    НоменклатураДокумента.ВидНоменклатуры,

|    НоменклатураДокумента.НаборСвойств,

|    НоменклатураДокумента.КоличествоВДокументе,

|    НоменклатураДокумента.СуммаВДокументе,

|    ЕСТЬNULL(СтоимостьМатериаловОстатки.СтоимостьОстаток, 0) КАК Стоимость,

|    ЕСТЬNULL(ОстаткиМатериаловОстатки.КоличествоОстаток, 0) КАК Количество

|ИЗ

|    НоменклатураДокумента КАК НоменклатураДокумента

…

Кроме того, понадобится изменить последний запрос, который при оперативном проведении проверяет, не появились ли отрицательные остатки. Теперь вы будете получать остатки не «вообще» для номенклатуры из табличной части документа, а для номенклатуры именно с тем набором свойств, который указан в строках документа (листинг 16.6).

Листинг 16.6. Контроль отрицательных остатков при оперативном проведении

…

Запрос3.Текст = "ВЫБРАТЬ

|    ОстаткиМатериаловОстатки.Материал,

|    ОстаткиМатериаловОстатки.НаборСвойств,

|    ОстаткиМатериаловОстатки.КоличествоОстаток

|ИЗ

|    РегистрНакопления.ОстаткиМатериалов.Остатки( , (Материал, НаборСвойств) В

|         (ВЫБРАТЬ

|              НоменклатураДокумента.Номенклатура,

|              НоменклатураДокумента.НаборСвойств

|         ИЗ

|              НоменклатураДокумента) И Склад = &Склад)

|    КАК ОстаткиМатериаловОстатки

|ГДЕ

|    ОстаткиМатериаловОстатки.КоличествоОстаток < 0";

 

Запрос3.УстановитьПараметр("Склад", Склад);

 

РезультатЗапроса = Запрос3.Выполнить();

ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

 

Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

Сообщение = Новый СообщениеПользователю();

Сообщение.Текст = "Не хватает " + Строка(- ВыборкаДетальныеЗаписи.КоличествоОстаток) + " единиц материала """ + ВыборкаДетальныеЗаписи.Материал + """" + " из набора свойств """ + ВыборкаДетальныеЗаписи.НаборСвойств + """";

Сообщение.Сообщить();

 

Отказ = Истина;

 

КонецЦикла;

…