Транспортные средства / Модуль объекта

// @strict-types

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда

#Область ОбработчикиСобытий

Процедура ПередЗаписью(Отказ)
	
	Если ОбменДанными.Загрузка Тогда
		Возврат;
	КонецЕсли;

	ОбновлениеИнформационнойБазы.ПроверитьОбъектОбработан(ЭтотОбъект);
	
	Код = ВРег(Код);
	Код = СтрЗаменить(Код, " ", "");
	
	ВместимостьПредставление = "";
	ПробелВСередине = "";
	Если ЗначениеЗаполнено(ГрузоподъемностьВТоннах) Тогда
		ВместимостьПредставление = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(НСтр("ru='%1 т'"), Строка(ГрузоподъемностьВТоннах));
		ПробелВСередине = " ";
	КонецЕсли;
	Если ЗначениеЗаполнено(ВместимостьВКубическихМетрах) Тогда
		ВместимостьПредставление = ВместимостьПредставление + ПробелВСередине
			+ СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(НСтр("ru='%1 м3'"), Строка(ВместимостьВКубическихМетрах));
	КонецЕсли;
		
КонецПроцедуры

Процедура ОбработкаЗаполнения(ДанныеЗаполнения, СтандартнаяОбработка)
	
	Если ТипЗнч(ДанныеЗаполнения) = Тип("СправочникСсылка.ТипыТранспортныхСредств") Тогда
		СтруктураРеквизитов = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(ДанныеЗаполнения,
			"ВместимостьВКубическихМетрах, ГрузоподъемностьВТоннах");
		ВместимостьВКубическихМетрах = СтруктураРеквизитов.ВместимостьВКубическихМетрах;
		ГрузоподъемностьВТоннах = СтруктураРеквизитов.ГрузоподъемностьВТоннах;
		Тип = ДанныеЗаполнения;
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

#КонецЕсли