← К списку

Виды планов / Форма списка / Модуль формы

файл

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Если Параметры.Свойство("АвтоТест") Тогда // Возврат при получении формы для анализа.
		Возврат;
	КонецЕсли;

	Если Параметры.Отбор.Свойство("Владелец") Тогда
		Элементы.Владелец.Видимость = Ложь;
	КонецЕсли; 

	//// СтандартныеПодсистемы.ПодключаемыеКоманды
	//ПодключаемыеКоманды.ПриСозданииНаСервере(ЭтотОбъект);
	//// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
	
	СобытияФорм.ПриСозданииНаСервере(ЭтаФорма, Отказ, СтандартнаяОбработка);

	// СтандартныеПодсистемы.ВерсионированиеОбъектов
	ВерсионированиеОбъектов.ПриСозданииНаСервере(ЭтотОбъект);
	// Конец СтандартныеПодсистемы.ВерсионированиеОбъектов
	
	//++ Локализация
	
	// ПрогнозированиеПродаж
	ИспользоватьПланированиеПродаж             = ПолучитьФункциональнуюОпцию("ИспользоватьПланированиеПродаж");
	ИспользоватьПланированиеПродажПоКатегориям = ПолучитьФункциональнуюОпцию("ИспользоватьПланированиеПродажПоКатегориям");
	Если ИспользоватьПланированиеПродаж
		Или ИспользоватьПланированиеПродажПоКатегориям Тогда
		СервисПрогнозированияПереопределяемый.ПроверитьВозможностьПоказаРекламы(
			Элементы.ГруппаБаннерСервисаПрогнозирования,
			Элементы.ТекстВозможностиИспользованияСервиса,
			ТребуетсяОбновитьИнформациюОВозможностиИспользованияСервисаПрогнозирования);
	КонецЕсли;
	// Конец ПрогнозированиеПродаж
	
	//-- Локализация
	
КонецПроцедуры

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	
	//++ Локализация
	
	// ПрогнозированиеПродаж
	Если ТребуетсяОбновитьИнформациюОВозможностиИспользованияСервисаПрогнозирования Тогда
		ПодключитьОбработчикОжидания("ОбновитьИнформациюОВозможностиИспользованияСервисаПрогнозирования", 1, Истина);
	КонецЕсли;
	// Конец ПрогнозированиеПродаж
	
	//-- Локализация
	
КонецПроцедуры

&НаКлиенте
Процедура ПриЗакрытии(ЗавершениеРаботы)
	
	Если ЗавершениеРаботы Тогда
		Возврат;
	КонецЕсли;
	
	//++ Локализация
	
	// ПрогнозированиеПродаж
	Если ЗначениеЗаполнено(ИдентификаторЗаданияСервисПрогнозирования) Тогда
		ОтменитьВыполнениеЗадания(ИдентификаторЗаданияСервисПрогнозирования);
	КонецЕсли;
	// Конец ПрогнозированиеПродаж
	
	//-- Локализация
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовШапкиФормы

&НаКлиенте
Процедура ТекстВозможностиИспользованияСервисаОбработкаНавигационнойСсылки(Элемент, НавигационнаяСсылкаФорматированнойСтроки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	//++ Локализация
	ОткрытьФорму("Обработка.ПанельУправленияСервисомПрогнозирования.Форма.МастерПодключенияКСервису");
	//-- Локализация
	
КонецПроцедуры

&НаКлиенте
Процедура ЗакрытьБаннерНажатие(Элемент)
	
	//++ Локализация
	Элементы.ГруппаБаннерСервисаПрогнозирования.Видимость = Ложь;
	ЗакрытьБаннерНажатиеНаСервере();
	//-- Локализация
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиКомандФормы

&НаКлиенте
Процедура Подключаемый_ВыполнитьПереопределяемуюКоманду(Команда)
	
	СобытияФормКлиент.ВыполнитьПереопределяемуюКоманду(ЭтаФорма, Команда);
	
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

//++ Локализация

#Область СервисПрогнозирования

&НаКлиенте
Процедура ОбновитьИнформациюОВозможностиИспользованияСервисаПрогнозирования()
	
	ДлительнаяОперация = НачатьОбновлениеИнформацииОВозможностиИспользованияСервисаПрогнозирования(УникальныйИдентификатор);
	Если ДлительнаяОперация = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	Если ДлительнаяОперация.Статус <> "Ошибка" Тогда
		ИдентификаторЗаданияСервисПрогнозирования = ДлительнаяОперация.ИдентификаторЗадания;
		
		НастройкиОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект);
		НастройкиОжидания.ВыводитьОкноОжидания = Ложь;
		Обработчик = Новый ОписаниеОповещения(
			"ПослеОбновленияИнформацииОВозможностиИспользованияСервисаПрогнозирования",
			ЭтотОбъект);
		ДлительныеОперацииКлиент.ОжидатьЗавершение(ДлительнаяОперация, Обработчик, НастройкиОжидания);
		
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура ПослеОбновленияИнформацииОВозможностиИспользованияСервисаПрогнозирования(ДлительнаяОперация, Контекст) Экспорт
	
	Если ДлительнаяОперация = Неопределено Тогда
		Возврат;
	КонецЕсли;
	Если ДлительнаяОперация.Статус <> "Выполнено" Тогда
		Возврат;
	КонецЕсли;
	ИдентификаторЗаданияСервисПрогнозирования = "";
	
	ДостаточноДанных = ПолучитьИзВременногоХранилища(ДлительнаяОперация.АдресРезультата);
	Элементы.ГруппаБаннерСервисаПрогнозирования.Видимость = ДостаточноДанных;
	
КонецПроцедуры

&НаСервереБезКонтекста
Функция НачатьОбновлениеИнформацииОВозможностиИспользованияСервисаПрогнозирования(УникальныйИдентификатор)
	
	ПараметрыВыполнения = ДлительныеОперации.ПараметрыВыполненияФункции(УникальныйИдентификатор);
	ПараметрыВыполнения.НаименованиеФоновогоЗадания = НСтр(
		"ru = 'Обновление информации о возможности использования сервиса прогнозирования в фоне'");
	ПараметрыВыполнения.ОжидатьЗавершение = 0;
	Возврат ДлительныеОперации.ВыполнитьФункцию(ПараметрыВыполнения,
		"СервисПрогнозированияПереопределяемый.ОбновленнаяИнформацияОДостаточностиДанныхДляПостроенияПрогноза");
	
КонецФункции

&НаСервереБезКонтекста
Процедура ЗакрытьБаннерНажатиеНаСервере()
	
	СервисПрогнозированияПереопределяемый.ДобавитьПользователяВЗакрывшиеРекламу();
	
КонецПроцедуры

&НаСервереБезКонтекста
Процедура ОтменитьВыполнениеЗадания(ИдентификаторЗадания)
	
	Если ТипЗнч(ИдентификаторЗадания) = Тип("Строка") Тогда
		ДлительныеОперации.ОтменитьВыполнениеЗадания(Новый УникальныйИдентификатор(ИдентификаторЗадания));
	Иначе
		ДлительныеОперации.ОтменитьВыполнениеЗадания(ИдентификаторЗадания);
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

//-- Локализация

#КонецОбласти

Связанные материалы