Авансовый отчет / Реквизиты счета-фактуры / Модуль формы

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Если Параметры.Свойство("АвтоТест") Тогда // Возврат при получении формы для анализа.
		Возврат;
	КонецЕсли;
	
	Номер           = Параметры.НомерСФ;
	Дата            = Параметры.ДатаСФ;
	Организация     = Параметры.Организация;
	Контрагент      = Параметры.Контрагент;
	СчетФактура     = Параметры.СчетФактура;
	ВыбраннаяСтрока = Параметры.ВыбраннаяСтрока;
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовШапкиФормы

&НаКлиенте
Процедура НомерПриИзменении(Элемент)
	
	СчетФактура = Неопределено;
	
КонецПроцедуры

&НаКлиенте
Процедура ДатаПриИзменении(Элемент)
	
	СчетФактура = Неопределено;
	
КонецПроцедуры

&НаКлиенте
Процедура СчетФактураПриИзменении(Элемент)
	
	Если ЗначениеЗаполнено(СчетФактура) Тогда
		СчетФактураПриИзмененииНаСервере();
	КонецЕсли;
	
КонецПроцедуры

&НаСервере
Процедура СчетФактураПриИзмененииНаСервере()
	
	ЗаполнитьЗначенияСвойств(ЭтотОбъект, ОбщегоНазначения.ЗначенияРеквизитовОбъекта(СчетФактура, "Номер, Дата"));
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиКомандФормы

&НаКлиенте
Процедура ОК(Команда)
	
	РеквизитыСчетФактуры = Новый Структура;
	РеквизитыСчетФактуры.Вставить("НомерСФ", Номер);
	РеквизитыСчетФактуры.Вставить("ДатаСФ", Дата);
	РеквизитыСчетФактуры.Вставить("СчетФактура", СчетФактура);
	РеквизитыСчетФактуры.Вставить("ВыбраннаяСтрока", ВыбраннаяСтрока);
	
	Закрыть(РеквизитыСчетФактуры);
	
КонецПроцедуры

&НаКлиенте
Процедура Отмена(Команда)
	
	Модифицированность = Ложь;
	Закрыть();
	
КонецПроцедуры

#КонецОбласти