#Область ОбработчикиСобытийФормы
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
УстановитьУсловноеОформлениеСписка();
Если Параметры.Свойство("ПоказыватьНеиспользуемыеТерритории") Тогда
ПоказыватьНеиспользуемыеТерритории = Параметры.ПоказыватьНеиспользуемыеТерритории;
КонецЕсли;
Если Параметры.РежимВыбора Тогда
Элементы.Список.РежимВыбора = Истина;
Если ЗначениеЗаполнено(Параметры.ТекущаяСтрока) Тогда
ПоказыватьНеиспользуемыеТерритории = Параметры.ТекущаяСтрока.ВАрхиве;
КонецЕсли;
КонецЕсли;
УстановитьОтборСписка(Список.Отбор, ПоказыватьНеиспользуемыеТерритории);
ЗарплатаКадры.ПриСозданииНаСервереФормыСДинамическимСписком(ЭтотОбъект, "Список");
КонецПроцедуры
#КонецОбласти
#Область ОбработчикиСобытийЭлементовШапкиФормы
&НаСервере
Процедура СписокПередЗагрузкойПользовательскихНастроекНаСервере(Элемент, Настройки)
ЗарплатаКадры.ПроверитьПользовательскиеНастройкиДинамическогоСписка(ЭтотОбъект, Настройки);
КонецПроцедуры
&НаСервере
Процедура СписокПриОбновленииСоставаПользовательскихНастроекНаСервере(СтандартнаяОбработка)
ЗарплатаКадры.ПроверитьПользовательскиеНастройкиДинамическогоСписка(ЭтотОбъект, , СтандартнаяОбработка);
КонецПроцедуры
&НаКлиенте
Процедура ПоказыватьНеиспользуемыеТерриторииПриИзменении(Элемент)
УстановитьОтборСписка(Список.Отбор, ПоказыватьНеиспользуемыеТерритории);
КонецПроцедуры
#КонецОбласти
#Область СлужебныеПроцедурыИФункции
&НаКлиентеНаСервереБезКонтекста
Процедура УстановитьОтборСписка(ГруппаОтбора, ПоказыватьНеиспользуемыеПоказатели)
ОбщегоНазначенияКлиентСервер.УдалитьЭлементыГруппыОтбора(ГруппаОтбора, "ВАрхиве");
Если Не ПоказыватьНеиспользуемыеПоказатели Тогда
ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбора(ГруппаОтбора, "ВАрхиве", Ложь);
КонецЕсли;
КонецПроцедуры
&НаСервере
Процедура УстановитьУсловноеОформлениеСписка()
ТекущийШрифт = Элементы.Список.Шрифт;
ЗачеркнутыйШрифт = Новый Шрифт(ТекущийШрифт,,,,,,Истина);
ЭлементОформления = Список.УсловноеОформление.Элементы.Добавить();
ЭлементОформления.Оформление.УстановитьЗначениеПараметра("Шрифт", ЗачеркнутыйШрифт);
ЭлементОформления.Использование = Истина;
ЭлементОтбора = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
ЭлементОтбора.Использование = Истина;
ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("ВАрхиве");
ЭлементОтбора.ПравоеЗначение = Истина;
КонецПроцедуры
#КонецОбласти
