← К списку

Способы выплаты зарплаты / Форма списка / Модуль формы

файл
#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	ПоказыватьНеиспользуемые = Ложь;
	УстановитьОтборИспользуемых();
	
	ЗарплатаКадры.ПриСозданииНаСервереФормыСДинамическимСписком(ЭтотОбъект, "Список",,,, "ВидДокументаОснования, ГруппаВидовДоговоров, ПометкаУдаления");
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовШапкиФормы

&НаКлиенте
Процедура ПоказыватьНеиспользуемыеПриИзменении(Элемент)
	УстановитьОтборИспользуемых()
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовТаблицыФормыСписок

&НаСервере
Процедура СписокПередЗагрузкойПользовательскихНастроекНаСервере(Элемент, Настройки)
	ЗарплатаКадры.ПроверитьПользовательскиеНастройкиДинамическогоСписка(ЭтотОбъект, Настройки);
КонецПроцедуры

&НаСервере
Процедура СписокПриОбновленииСоставаПользовательскихНастроекНаСервере(СтандартнаяОбработка)
	
	ЗарплатаКадры.ПроверитьПользовательскиеНастройкиДинамическогоСписка(ЭтотОбъект, , СтандартнаяОбработка);
	
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

&НаСервере
Процедура УстановитьОтборИспользуемых()
	
	ОбщегоНазначенияКлиентСервер.УдалитьЭлементыГруппыОтбора(Список.Отбор, "ГруппаВидовДоговоров");
	ОбщегоНазначенияКлиентСервер.УдалитьЭлементыГруппыОтбора(Список.Отбор, "ВидДокументаОснования");
	ОбщегоНазначенияКлиентСервер.УдалитьЭлементыГруппыОтбора(Список.Отбор, "ПометкаУдаления");
	
	Если ПоказыватьНеиспользуемые Тогда
		ДоступныеГруппыВидовДоговоров = Перечисления.ГруппыВидовДоговоровССотрудникамиДляВыплатыЗарплаты.ДоступныеПоМетаданным();
		ДоступныеГруппыВидовДоговоров.Добавить(Перечисления.ГруппыВидовДоговоровССотрудникамиДляВыплатыЗарплаты.ПустаяСсылка());
	Иначе	
		ДоступныеГруппыВидовДоговоров = Перечисления.ГруппыВидовДоговоровССотрудникамиДляВыплатыЗарплаты.ДоступныеПоФункциональнымОпциям();	
	КонецЕсли;
	ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбора(
		Список.Отбор, 
		"ГруппаВидовДоговоров", 
		ДоступныеГруппыВидовДоговоров,
		ВидСравненияКомпоновкиДанных.ВСписке);
		
	Если ПоказыватьНеиспользуемые Тогда
		ДоступныеВидыДокументов = Перечисления.ВидыДокументовОснованийВедомостейНаВыплатуЗарплаты.ДоступныеПоМетаданным();	
	Иначе		
		ДоступныеВидыДокументов = Перечисления.ВидыДокументовОснованийВедомостейНаВыплатуЗарплаты.ДоступныеПоФункциональнымОпциям();	
	КонецЕсли;
	ДоступныеВидыДокументов.Добавить(Перечисления.ВидыДокументовОснованийВедомостейНаВыплатуЗарплаты.ПустаяСсылка());
	ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбора(
		Список.Отбор, 
		"ВидДокументаОснования", 
		ДоступныеВидыДокументов,
		ВидСравненияКомпоновкиДанных.ВСписке);
		
	Если Не ПоказыватьНеиспользуемые Тогда
		ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбора(
			Список.Отбор, 
			"ПометкаУдаления", 
			Ложь);
	КонецЕсли	
	
КонецПроцедуры	

#КонецОбласти

Связанные материалы