← К списку

Основания увольнения / Модуль менеджера

файл

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда
	
#Область ПрограммныйИнтерфейс

#Область ДляВызоваИзДругихПодсистем

// ТехнологияСервиса.ВыгрузкаЗагрузкаДанных

// Возвращает реквизиты справочника, которые образуют естественный ключ для элементов справочника.
//
// Возвращаемое значение:
//  Массив из Строка - имена реквизитов, образующих естественный ключ.
//
Функция ПоляЕстественногоКлюча() Экспорт
	
	Результат = Новый Массив;
	
	Результат.Добавить("Наименование");
	
	Возврат Результат;
	
КонецФункции

// Конец ТехнологияСервиса.ВыгрузкаЗагрузкаДанных

#КонецОбласти

#КонецОбласти

#КонецЕсли

#Область ОбработчикиСобытий

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда

Процедура ОбработкаПолученияФормы(ВидФормы, Параметры, ВыбраннаяФорма, ДополнительнаяИнформация, СтандартнаяОбработка)
	КадровыйУчет.ОснованияУвольненияОбработкаПолученияФормы(ВидФормы, Параметры, ВыбраннаяФорма, ДополнительнаяИнформация, СтандартнаяОбработка);
КонецПроцедуры

Процедура ОбработкаПолученияДанныхВыбора(ДанныеВыбора, Параметры, СтандартнаяОбработка)
	КадровыйУчет.ОбработкаПолученияДанныхВыбораОснованийУвольнения(
		ДанныеВыбора, Параметры, СтандартнаяОбработка);
КонецПроцедуры

#КонецЕсли

Процедура ОбработкаПолученияПредставления(Данные, Представление, СтандартнаяОбработка)
	ПредставленияОбщихДанныхВызовСервера.ОбработкаПолученияПредставления(Данные, Представление, СтандартнаяОбработка);
КонецПроцедуры

#КонецОбласти

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда

#Область СлужебныеПроцедурыИФункции

#Область ПервоначальноеЗаполнениеИОбновлениеИнформационнойБазы

// Процедура выполняет первоначальное заполнение статей ТК - оснований увольнения.
Процедура НачальноеЗаполнение() Экспорт
	
	Запрос = Новый Запрос;
	Запрос.Текст =
		"ВЫБРАТЬ ПЕРВЫЕ 1
		|	ПричиныУвольненияПФР.Ссылка КАК Ссылка
		|ИЗ
		|	Справочник.ПричиныУвольненияПФР КАК ПричиныУвольненияПФР
		|ГДЕ
		|	НЕ ПричиныУвольненияПФР.Предопределенный";
	
	Если Запрос.Выполнить().Пустой() Тогда
		Справочники.ПричиныУвольненияПФР.НачальноеЗаполнение();
	КонецЕсли;
	
	ЗагрузитьКлассификатор();
	
КонецПроцедуры

Процедура ЗагрузитьКлассификатор() Экспорт
	
	ОбновитьСтатьиУвольненияУмершихСотрудников();
	
	КадровыйУчет.ЗаполнитьКлассификаторОснованийУвольнения(
		Метаданные.Справочники.ОснованияУвольнения.Имя,
		ПолучитьМакет("ОснованияУвольненияПоТКРФ"));
	
КонецПроцедуры

Процедура ОбновитьОснованияВАрхиве(ПараметрыОбновления = Неопределено) Экспорт
	КадровыйУчет.ОбновитьОснованияУвольненияВАрхиве(
		Метаданные.Справочники.ОснованияУвольнения.Имя);
КонецПроцедуры

Процедура ОбновитьСтатьиУвольненияУмершихСотрудников()
	
	КадровыйУчет.УстановитьИмяПредопределенногоОснованиюУвольнения(
		Метаданные.Справочники.ОснованияУвольнения.Имя, "Статья83ч1п6", НСтр("ru = 'п. 6 ч. 1 ст. 83'"));
	
КонецПроцедуры

Процедура ИсправитьОшибочнуюСтатьюОснования() Экспорт
	
	СтатьяСОпечаткой = Справочники.ОснованияУвольнения.НайтиПоНаименованию(НСтр("ru = 'п. 7 ч. 1 ст. 81 (Физческое лицо)'"), Истина);
	Если Не СтатьяСОпечаткой.Пустая()
		И Не ОбщегоНазначения.ЗначениеРеквизитаОбъекта(СтатьяСОпечаткой, "ПометкаУдаления") Тогда
		
		СтатьяСОпечаткойОбъект = СтатьяСОпечаткой.ПолучитьОбъект();
		СтатьяСВернымНаименованием = Справочники.ОснованияУвольнения.НайтиПоНаименованию(НСтр("ru = 'п. 7 ч. 1 ст. 83 (Физическое лицо)'"), Истина);
		Если СтатьяСВернымНаименованием = Неопределено Тогда
			СтатьяСОпечаткойОбъект.Наименование = НСтр("ru = 'п. 7 ч. 1 ст. 81 (Физическое лицо)'");
		Иначе
			СтатьяСОпечаткойОбъект.ПометкаУдаления = Истина;
		КонецЕсли;
		ОбновлениеИнформационнойБазы.ЗаписатьОбъект(СтатьяСОпечаткойОбъект);
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

#КонецОбласти

#КонецЕсли

Связанные материалы