Учетная политика финансового учета / Редактирование истории / Модуль формы

#Область ОписаниеПеременных

&НаКлиенте
Перем ПараметрыУдаления;

#КонецОбласти

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Организация = Параметры.Организация;
	ТолькоПросмотр = Параметры.ТолькоПросмотр;
	
	ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбораДинамическогоСписка(Список,
		"Организация",
		Организация,
		ВидСравненияКомпоновкиДанных.Равно, , 
		ЗначениеЗаполнено(Организация),,);
		
	ДоступнаНастройкаВНА = Ложь;
	РегламентированныйУчетВНА = Ложь;
	
	//++ НЕ УТ
	ДоступнаНастройкаВНА = ПолучитьФункциональнуюОпцию("ИспользоватьВнеоборотныеАктивы2_4");
	РегламентированныйУчетВНА = ПолучитьФункциональнуюОпцию("РегламентированныйУчетВНА");
	//-- НЕ УТ
	
	Если ДоступнаНастройкаВНА Тогда
		
		Если РегламентированныйУчетВНА Тогда
			Элементы.СписокПорядокНачисленияАмортизацииОСРегл.Видимость = Ложь;
			Элементы.СписокПорядокНачисленияАмортизацииРеглАренда.Видимость = Ложь;
			Элементы.СписокПорядокНачисленияАмортизацииНМАРегл.Видимость = Ложь;
			Элементы.СписокПорядокУчетаВНАРегл.Видимость = Ложь;
		КонецЕсли;
		
	Иначе
		Элементы.СписокПорядокНачисленияАмортизацииОС.Видимость = Ложь;
		Элементы.СписокПорядокНачисленияАмортизацииАренда.Видимость = Ложь;
		Элементы.СписокПорядокНачисленияАмортизацииНМА.Видимость = Ложь;
		Элементы.СписокПорядокНачисленияАмортизацииОСРегл.Видимость = Ложь;
		Элементы.СписокПорядокНачисленияАмортизацииРеглАренда.Видимость = Ложь;
		Элементы.СписокПорядокНачисленияАмортизацииНМАРегл.Видимость = Ложь;
		Элементы.СписокУчетАрендыПоФСБУ25_2018.Видимость = Ложь;
		Элементы.СписокПорядокУчетаВНАРегл.Видимость = Ложь;
		Элементы.СписокМетодПереоценкиОС.Видимость = Ложь;
		Элементы.СписокМетодПереоценкиНМА.Видимость = Ложь;
	КонецЕсли;
			
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовШапкиФормы

&НаКлиенте
Процедура Добавить(Команда)
	ОповеститьОВыборе(Новый Структура("Организация, Период", 
		Организация,
		ОбщегоНазначенияКлиент.ДатаСеанса()));
КонецПроцедуры

&НаКлиенте
Процедура СписокВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
	ОповеститьОВыборе(ВыбраннаяСтрока);
	СтандартнаяОбработка = Ложь;
КонецПроцедуры

&НаКлиенте
Процедура Выбрать(Команда)
	ОповеститьОВыборе(Элементы.Список.ТекущаяСтрока);
КонецПроцедуры

&НаСервереБезКонтекста
Процедура УдалитьСтавкиДисконтирования(Период, Организация)
	НаборЗаписей = РегистрыСведений.СтавкиДисконтирования.СоздатьНаборЗаписей();
	НаборЗаписей.Отбор.Период.Установить(Период);
	НаборЗаписей.Отбор.Организация.Установить(Организация);
	НаборЗаписей.Записать();
КонецПроцедуры

&НаКлиенте
Процедура СписокПослеУдаления(Элемент)
	Если ПараметрыУдаления <> Неопределено Тогда
		УдалитьСтавкиДисконтирования(ПараметрыУдаления.Период, ПараметрыУдаления.Организация);
		ПараметрыУдаления = Неопределено;
	КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура СписокПередУдалением(Элемент, Отказ)
	ТекущиеДанные = Элементы.Список.ТекущиеДанные;
	Если ТекущиеДанные <> Неопределено Тогда
		ПараметрыУдаления = Новый Структура;
		ПараметрыУдаления.Вставить("Период", ТекущиеДанные.Период);
		ПараметрыУдаления.Вставить("Организация", ТекущиеДанные.Организация);
	КонецЕсли;
КонецПроцедуры

#КонецОбласти