← К списку

Документы физических лиц / Форма записи / Модуль формы

файл

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	УстановитьВидимостьДоступность(ЭтотОбъект);
	УстановитьСвойстваЭлементовФормы(ЭтотОбъект);
	
	ОбновлениеИнформационнойБазы.ПроверитьОбъектОбработан(Запись, ЭтотОбъект);
	
КонецПроцедуры

&НаСервере
Процедура ПриЧтенииНаСервере(ТекущийОбъект)
	
	// СтандартныеПодсистемы.УправлениеДоступом
	УправлениеДоступом.ПриЧтенииНаСервере(ЭтотОбъект, ТекущийОбъект);
	// Конец СтандартныеПодсистемы.УправлениеДоступом
	
КонецПроцедуры

&НаСервере
Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)
	
	Если Не Запись.ЯвляетсяДокументомУдостоверяющимЛичность Тогда
		Возврат;
	КонецЕсли;
	
	Если ОбщегоНазначения.ПодсистемаСуществует("ЗарплатаКадрыКорпоративнаяПодсистемы.МедицинскоеСтрахование") Тогда
		МодульМедицинскоеСтрахованиеФормы = ОбщегоНазначения.ОбщийМодуль("МедицинскоеСтрахованиеФормы");
		МодульМедицинскоеСтрахованиеФормы.ПроверитьИзменениеДокументаУдостоверяющегоЛичностьИзФормыЗаписи(Запись);
	КонецЕсли;
	
КонецПроцедуры

&НаСервере
Процедура ПослеЗаписиНаСервере(ТекущийОбъект, ПараметрыЗаписи)
	
	// СтандартныеПодсистемы.УправлениеДоступом
	УправлениеДоступом.ПослеЗаписиНаСервере(ЭтотОбъект, ТекущийОбъект, ПараметрыЗаписи);
	// Конец СтандартныеПодсистемы.УправлениеДоступом
	
КонецПроцедуры

&НаКлиенте
Процедура ПослеЗаписи(ПараметрыЗаписи)
	
	Если Запись.ЯвляетсяДокументомУдостоверяющимЛичность Тогда
		ПараметрыЗаписи = Новый Структура;
		ПараметрыЗаписи.Вставить("ВидДокумента", Запись.ВидДокумента);
		ПараметрыЗаписи.Вставить("ПаспортСерия", Запись.Серия);
		ПараметрыЗаписи.Вставить("ПаспортНомер", Запись.Номер);
		ПараметрыЗаписи.Вставить("ПаспортВыдан", Запись.КемВыдан);
		ПараметрыЗаписи.Вставить("ПаспортДатаВыдачи", Запись.ДатаВыдачи);
		ПараметрыЗаписи.Вставить("Представление", Запись.Представление);
		Оповестить("Запись_ДокументФизЛица", ПараметрыЗаписи, ЭтаФорма);
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовШапкиФормы

&НаКлиенте
Процедура ВидДокументаПриИзменении(Элемент)
	
	Если ЯвляетсяУдостоверениемЛичности(Запись.Физлицо, Запись.ВидДокумента, Запись.Период) Тогда
		Запись.ЯвляетсяДокументомУдостоверяющимЛичность = Истина;
	КонецЕсли;
	
	//++ Локализация

	//++ НЕ УТ
	СотрудникиКлиентСервер.ОбновитьГруппуФамилияИмяЛатиницей(ЭтотОбъект, "Запись");
	//-- НЕ УТ

	//-- Локализация
	УстановитьСвойстваЭлементовФормы(ЭтотОбъект);
	
КонецПроцедуры

&НаКлиенте
Процедура КатегорииТранспортныхСредствНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	//++ Локализация

	//++ НЕ УТ
	ЗарплатаКадрыКлиент.ОткрытьФормуСпискаЗначенийСтроковогоРеквизита(Элемент, 
		СтандартнаяОбработка, "КатегорииТранспортныхСредств", НСтр("ru = 'Категории транспортных средств'"), НСтр("ru = 'Категории'"));
	//-- НЕ УТ

	//-- Локализация
	Возврат; // в УТ11 не используется
КонецПроцедуры

&НаКлиенте
Процедура КатегорииТранспортныхСредствОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
	
	Если ТипЗнч(ВыбранноеЗначение) = Тип("Строка") Тогда
		Запись.КатегорииТранспортныхСредств = ВыбранноеЗначение;
	КонецЕсли;	
	
КонецПроцедуры

&НаКлиенте
Процедура КатегорииТранспортныхСредствАвтоПодбор(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка)
	//++ Локализация

	//++ НЕ УТ
	ЗарплатаКадрыКлиент.ПодборЗначенияСтроковогоРеквизита(Текст, ДанныеВыбора, СтандартнаяОбработка, "КатегорииТранспортныхСредств");
	//-- НЕ УТ

	//-- Локализация
	Возврат; // в УТ11 не используется
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

&НаСервереБезКонтекста
Функция ЯвляетсяУдостоверениемЛичности(Физлицо, ВидДокумента, Дата)
	
	Возврат РегистрыСведений.ДокументыФизическихЛиц.ЯвляетсяУдостоверениемЛичности(Физлицо, ВидДокумента, Дата);
	
КонецФункции

&НаКлиентеНаСервереБезКонтекста
Процедура УстановитьВидимостьДоступность(Форма)
	//++ Локализация

	//++ НЕ УТ
	СотрудникиКлиентСервер.УстановитьВидимостьГруппыФамилияИмяЛатиницей(Форма, "Запись");
	//-- НЕ УТ

	//-- Локализация
	Возврат; // в УТ11 не используется
КонецПроцедуры

&НаКлиентеНаСервереБезКонтекста
Процедура УстановитьСвойстваЭлементовФормы(Форма)
	
	//++ Локализация

	//++ НЕ УТ
	СотрудникиКлиентСервер.УстановитьВидимостьГруппыФамилияИмяЛатиницей(Форма, "Запись");
	//-- НЕ УТ

	//-- Локализация
	
	ОбщегоНазначенияКлиентСервер.УстановитьСвойствоЭлементаФормы(
		Форма.Элементы, 
		"КатегорииТранспортныхСредств", 
		"Видимость", 
		Форма.Запись.ВидДокумента = ПредопределенноеЗначение("Справочник.ВидыДокументовФизическихЛиц.ВодительскоеУдостоверение"));
	
КонецПроцедуры

&НаКлиенте
Процедура ПередЗаписью(Отказ, ПараметрыЗаписи)
	//++ Локализация

	//++ НЕ УТ
	СотрудникиКлиентСервер.ПроверитьНаписаниеФИДокументаЛатинскими(ЭтотОбъект, "Запись", Отказ);
	//-- НЕ УТ

	//-- Локализация
	Возврат; // в УТ11 не используется
КонецПроцедуры

#КонецОбласти

Связанные материалы