Помощник оформления складских актов / Форма выбора организаций / Модуль формы

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	// Пропускаем инициализацию, чтобы гарантировать получение формы при передаче параметра "АвтоТест".
	Если Параметры.Свойство("АвтоТест") Тогда
		Возврат;
	КонецЕсли;
	
	Если Параметры.Свойство("МассивОрганизаций") Тогда
		Для Каждого Организация Из Параметры.МассивОрганизаций Цикл
			Строка = Объект.ВыбранныеОрганизации.Добавить();
			Строка.Организация = Организация;
			Строка.Картинка    = БиблиотекаКартинок.Организация;
		КонецЦикла;
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура ОбработкаВыбора(ВыбранноеЗначение, ИсточникВыбора)
	
	Если ТипЗнч(ВыбранноеЗначение) = Тип("Массив") Тогда
		
		Для Каждого Организация Из ВыбранноеЗначение Цикл
			ОтборСтрок  = Новый Структура("Организация", Организация);
			МассивСтрок = Объект.ВыбранныеОрганизации.НайтиСтроки(ОтборСтрок);
			
			Если МассивСтрок.Количество() = 0 Тогда
				НоваяСтрока = Объект.ВыбранныеОрганизации.Добавить();
				НоваяСтрока.Организация = Организация;
				НоваяСтрока.Картинка    = БиблиотекаКартинок.Организация;
			КонецЕсли;
		КонецЦикла;
		
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиКомандФормы

&НаКлиенте
Процедура КнопкаОК(Команда)
	
	МассивОрганизаций = Новый Массив;
	
	Для Каждого Строка Из Объект.ВыбранныеОрганизации Цикл
		МассивОрганизаций.Добавить(Строка.Организация);
	КонецЦикла;
	
	Закрыть(МассивОрганизаций);
	
КонецПроцедуры

&НаКлиенте
Процедура КнопкаОтмена(Команда)
	
	Закрыть(Неопределено);
	
КонецПроцедуры

&НаКлиенте
Процедура ПодборОрганизации(Команда)

	ОткрытьФорму("Справочник.Организации.ФормаВыбора",Новый Структура("РежимВыбора,МножественныйВыбор,ЗакрыватьПриВыборе",Истина,Истина,Ложь), ЭтаФорма,,,,,РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
	
КонецПроцедуры

&НаКлиенте
Процедура ПодборПоклажедателя(Команда)
		
	ОткрытьФорму("Обработка.ПомощникОформленияСкладскихАктов.Форма.ПодборПоклажедателя", Новый Структура("ЗакрыватьПриВыборе",Ложь), ЭтаФорма,,,,,РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
	
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

&НаКлиенте
Процедура ВыбранныеОрганизацииПередНачаломДобавления(Элемент, Отказ, Копирование, Родитель, Группа, Параметр)
	
	Отказ = Истина;
	
	ПараметрыФормы = Новый Структура("РежимВыбора, МножественныйВыбор, ЗакрыватьПриВыборе", Истина, Истина, Ложь);
	
	ОткрытьФорму("Справочник.Организации.ФормаВыбора", ПараметрыФормы, ЭтаФорма, , , , ,
		РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
	
КонецПроцедуры

#КонецОбласти