Платежный календарь / Настройки / Модуль формы

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	// Пропускаем инициализацию, чтобы гарантировать получение формы при передаче параметра "АвтоТест".
	Если Параметры.Свойство("АвтоТест") Тогда
		Возврат;
	КонецЕсли;
	
	ЗаполнитьЗначенияСвойств(Объект, Параметры.Объект, ИзменяемыеРеквизиты());
	
	ДоступнаАренда = Ложь;
	//++ НЕ УТ
	ДоступнаАренда = ВнеоборотныеАктивы.ИспользуетсяУправлениеВНА();
	//-- НЕ УТ
	Элементы.Аренда.Видимость = ДоступнаАренда;
	
КонецПроцедуры

&НаСервере
Процедура ОбработкаПроверкиЗаполненияНаСервере(Отказ, ПроверяемыеРеквизиты)
	
	ПроверяемыеРеквизиты.Очистить();
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиКомандФормы

&НаКлиенте
Процедура ПрименитьИЗакрыть(Команда)
	
	Если ПроверитьЗаполнение() Тогда
		Результат = Новый Структура(ИзменяемыеРеквизиты());
		ЗаполнитьЗначенияСвойств(Результат, Объект);
		Закрыть(Результат);
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

&НаКлиентеНаСервереБезКонтекста
Функция ИзменяемыеРеквизиты()
	
	Возврат "ПланироватьСДаты, ВалютаИтогов, СкрыватьВыходные, ГруппироватьПоВалютам,
		|НесогласованныеЗаявки, ОжидаемыеПоступления, ЗаказыКлиентов, ЗаказыПоставщикам, ВозвратыКлиентам, ВозвратыОтПоставщиков,
		|КредитыИлиЗаймыПолученные, Депозиты, ЗаймыВыданные, Аренда";
	
КонецФункции

#КонецОбласти