Документооборот с контролирующими органами / Сообщение об одобренном заявлении / Модуль формы

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	// Пропускаем инициализацию, чтобы гарантировать получение формы при передаче параметра "АвтоТест".
	Если Параметры.Свойство("АвтоТест") Тогда
		Возврат;
	КонецЕсли;
	
	СсылкаНаОбъект 	= Параметры.СсылкаНаОбъект;
	Заявление 		= Параметры.Заявление;
	
	Параметры.Свойство("ЭтоПодключениеНаправления", ЭтоПодключениеНаправления);
	
	УправлениеФормой();
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовШапкиФормы

#КонецОбласти

#Область ОбработчикиСобытийЭлементовТаблицыФормы

#КонецОбласти

#Область ОбработчикиКомандФормы

&НаКлиенте
Процедура ЗавершитьНастройкуСейчас(Команда)
	Закрыть("ЗавершитьНастройкуСейчас");
КонецПроцедуры

&НаКлиенте
Процедура БольшеНеПоказывать(Команда)
	Закрыть("БольшеНеПоказывать");
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

&НаСервере
Процедура УправлениеФормой()
	
	НазваниеВРодительномПадеже 	= ДлительнаяОтправкаКлиентСервер.НазваниеОбъектаВРодительномПадеже(СсылкаНаОбъект);
	Заголовок = СтрЗаменить(Заголовок, "<отчета>", НазваниеВРодительномПадеже);
	
	РазрешеноПропуститьПредупреждение = Заявление.ТипЗаявления = Перечисления.ТипыЗаявленияАбонентаСпецоператораСвязи.Изменение
		И НЕ ЭтоПодключениеНаправления;
	
	Если РазрешеноПропуститьПредупреждение Тогда
		УправлениеФормойЕслиРазрешеноПропуститьПредупреждение(НазваниеВРодительномПадеже);
	Иначе
		УправлениеФормойЕслиНеРазрешеноПропуститьПредупреждение(НазваниеВРодительномПадеже);
	КонецЕсли;
	
	// Представление заявления
	КонтекстЭДОСервер  =  ДокументооборотСКО.ПолучитьОбработкуЭДО();
	КонтекстЭДОСервер.УстановитьПредставлениеЗаявленияВВидеФорматированнойСтроки(Заявление, Элементы.ЗаявлениеОдобрено);
	
КонецПроцедуры

&НаСервере
Процедура УправлениеФормойЕслиРазрешеноПропуститьПредупреждение(НазваниеВРодительномПадеже)
	
	Элементы.ФормаЗакрыть.Видимость 		= Ложь;
	Элементы.ЧтоДелатьПервичное.Видимость 	= Ложь;
	
	НазваниеВИменительномПадеже = ДлительнаяОтправкаКлиентСервер.НазваниеОбъектаВИменительномПадеже(СсылкаНаОбъект);
	
	Элементы.ЧтоДелатьВторичное.Заголовок = СтрЗаменить(Элементы.ЧтоДелатьВторичное.Заголовок, "<отчета>", 	НазваниеВРодительномПадеже);
	Элементы.ЧтоДелатьВторичное.Заголовок = СтрЗаменить(Элементы.ЧтоДелатьВторичное.Заголовок, "<отчет>", 	НазваниеВИменительномПадеже);
	
КонецПроцедуры
	
&НаСервере
Процедура УправлениеФормойЕслиНеРазрешеноПропуститьПредупреждение(НазваниеВРодительномПадеже)
	
	Элементы.ЧтоДелатьВторичное.Видимость 		= Ложь;
	Элементы.ФормаБольшеНеПоказывать.Видимость 	= Ложь;
	
	Элементы.ЧтоДелатьПервичное.Заголовок = СтрЗаменить(Элементы.ЧтоДелатьПервичное.Заголовок, "<отчета>",  НазваниеВРодительномПадеже);
	
КонецПроцедуры	

#КонецОбласти