Параметры начисления транспортного налога / Выбор кода вида транспортного средства / Модуль формы

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Если Параметры.Свойство("АвтоТест") Тогда
		Возврат;
	КонецЕсли;
	
	Если Параметры.Свойство("Дата") Тогда 
		
		Если Год(Параметры.Дата) < 2012 Тогда
			Макет = Отчеты.РегламентированныйОтчетТранспортныйНалог.ПолучитьМакет("Списки2007Кв1");
			ИмяОбласти = "ВидыТранспортныхСредств";
		ИначеЕсли Год(Параметры.Дата) = 2012 Тогда 
			Макет = Отчеты.РегламентированныйОтчетТранспортныйНалог.ПолучитьМакет("Списки2012Кв1");
			ИмяОбласти = "ВидыТранспортныхСредств";
		ИначеЕсли Год(Параметры.Дата) < 2019 Тогда 
			Макет = Отчеты.РегламентированныйОтчетТранспортныйНалог.ПолучитьМакет("Списки2012Кв1");
			ИмяОбласти = "ВидыТранспортныхСредств2013";
		Иначе 
			Макет = Отчеты.РегламентированныйОтчетТранспортныйНалог.ПолучитьМакет("СпискиВыбора2019Кв1");
			ИмяОбласти = "ВидыТранспортныхСредств";
		КонецЕсли;
		
	Иначе
		
		Макет = Отчеты.РегламентированныйОтчетТранспортныйНалог.ПолучитьМакет("СпискиВыбора2019Кв1");
		ИмяОбласти = "ВидыТранспортныхСредств";
		
	КонецЕсли;
	
	ТекущаяОбласть = Макет.Области.Найти(ИмяОбласти);
	
	Если НЕ (ТекущаяОбласть = Неопределено) Тогда	
	
		Для НомерСтр = ТекущаяОбласть.Верх По ТекущаяОбласть.Низ Цикл
			
			// Перебираем строки макета.
			КодПоказателя = СокрП(Макет.Область(НомерСтр, 1).Текст);
			Название      = СокрП(Макет.Область(НомерСтр, 2).Текст);
			
			Если КодПоказателя = "###" Тогда
				Прервать;
			ИначеЕсли ПустаяСтрока(КодПоказателя) Тогда
				Продолжить;
			Иначе
				НоваяСтрока = СписокКодов.Добавить();
				НоваяСтрока.Код          = КодПоказателя;
				НоваяСтрока.Наименование = Название;
			КонецЕсли;
		
		КонецЦикла;
		
	КонецЕсли;
	
	Если ЗначениеЗаполнено(Параметры.ТекущийКод) Тогда
		СтрокиКодов = СписокКодов.НайтиСтроки(Новый Структура("Код", Параметры.ТекущийКод));
		Если СтрокиКодов.Количество() > 0 Тогда
			Элементы.СписокКодов.ТекущаяСтрока = СтрокиКодов[0].ПолучитьИдентификатор();
		КонецЕсли;
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовФормы

&НаКлиенте
Процедура ВыборЭлемента()
	
	СтрокаТаблицы = Элементы.СписокКодов.ТекущиеДанные;
	
	ВозвращаемыеПараметры = Новый Структура("КодВидаТС, Наименование",СтрокаТаблицы.Код,СтрокаТаблицы.Наименование);
	Закрыть(ВозвращаемыеПараметры);
	
КонецПроцедуры

&НаКлиенте
Процедура СписокКодовВыборЗначения(Элемент, Значение, СтандартнаяОбработка)
	
	ВыборЭлемента();
	
КонецПроцедуры

#КонецОбласти