Возвращает структуру для удобства описания поставляемых профилей.

Синтаксис

Функция НовоеОписаниеПрофиляГруппДоступа() Экспорт

Возвращаемое значение

Структура:

• Имя - Строка - может использоваться в программном интерфейсе, например, в процедуре ВключитьПрофильПользователю.
• Родитель - Строка - имя папки профилей, в которую входит профиль.
• Идентификатор - Строка - строка уникального идентификатора поставляемого профиля, которая используется для поиска в базе данных. Чтобы получить идентификатор, нужно создать профиль в режиме 1С:Предприятие и получить уникальный идентификатор ссылки. Не следует указывать идентификаторы, полученные произвольным способом, т.к. это может нарушить уникальность ссылок.
• Наименование - Строка - наименование поставляемого профиля.
• Описание - Строка - описание поставляемого профиля.
• Роли - Массив из Строка - имена ролей поставляемого профиля.
• Назначение - Массив из Тип - типы ссылок пользователя и объектов авторизации внешних пользователей. Если пустой, значит, назначение для пользователей. Должны быть в пределах состава определяемого типа Пользователь.
• ВидыДоступа - СписокЗначений: ** Значение - Строка - имя вида доступа, указанного в переопределяемом модуле УправлениеДоступомПереопределяемый в процедуре ПриЗаполненииВидовДоступа. ** Представление - Строка - допустимы строки "ВначалеВсеЗапрещены" (или пустая строка), "ВначалеВсеРазрешены", "Предустановленный".
• ЗначенияДоступа - СписокЗначений: ** Значение - Строка - имя вида доступа, указанного в параметре ВидыДоступа. ** Представление - Строка - имя предопределенного элемента, например "Справочник.ГруппыПользователей.ВсеПользователи".

Пример вызова

// Профиль "Пользователь".
ОписаниеПрофиля = УправлениеДоступом.НовоеОписаниеПрофиляГруппДоступа();
ОписаниеПрофиля.Имя           = "Пользователь";
ОписаниеПрофиля.Идентификатор = "09e56dbf-90a0-11de-862c-001d600d9ad2";
ОписаниеПрофиля.Наименование  = НСтр("ru = 'Пользователь'", ОбщегоНазначения.КодОсновногоЯзыка());
// Переопределение назначения.
ОбщегоНазначенияКлиентСервер.ДополнитьМассив(ОписаниеПрофиля.Назначение,
 Метаданные.ОпределяемыеТипы.ВнешнийПользователь.Тип.Типы());
ОписаниеПрофиля.Описание =
 НСтр("ru = 'Общие разрешенные действия для большинства пользователей.
            |Как правило, это права на просмотр данных информационной системы.'");
// Использование 1С:Предприятия.
ОписаниеПрофиля.Роли.Добавить("ЗапускТонкогоКлиента");
ОписаниеПрофиля.Роли.Добавить("ВыводНаПринтерФайлБуферОбмена");
ОписаниеПрофиля.Роли.Добавить("СохранениеДанныхПользователя");
// ...
// Использование программы.
ОписаниеПрофиля.Роли.Добавить("БазовыеПраваБСП");
ОписаниеПрофиля.Роли.Добавить("ПросмотрОписанияИзмененийПрограммы");
ОписаниеПрофиля.Роли.Добавить("ИзменениеТекущегоПользователя");
// ...
// Использование НСИ.
ОписаниеПрофиля.Роли.Добавить("ЧтениеБазовойНСИ");
ОписаниеПрофиля.Роли.Добавить("ЧтениеОбщейБазовойНСИ");
// ...
// Типовые возможности.
ОписаниеПрофиля.Роли.Добавить("ДобавлениеИзменениеЛичныхВариантовОтчетов");
ОписаниеПрофиля.Роли.Добавить("ПросмотрСвязанныеДокументы");
// ...
// Основные возможности профиля.
ОписаниеПрофиля.Роли.Добавить("ДобавлениеИзменениеЗаметок");
ОписаниеПрофиля.Роли.Добавить("ДобавлениеИзменениеНапоминаний");
ОписаниеПрофиля.Роли.Добавить("ДобавлениеИзменениеЗаданий");
ОписаниеПрофиля.Роли.Добавить("ИзменениеВыполнениеЗадач");
// ...
// Виды ограничения доступа профиля.
ОписаниеПрофиля.ВидыДоступа.Добавить("Организации");
ОписаниеПрофиля.ВидыДоступа.Добавить("Пользователи", "Предустановленный");
ОписаниеПрофиля.ВидыДоступа.Добавить("ХозяйственныеОперации", "Предустановленный");
ОписаниеПрофиля.ЗначенияДоступа.Добавить("ХозяйственныеОперации",
 "Перечисление.ХозяйственныеОперации.ВыдачаДенежныхСредствПодотчетнику");
// ...
ОписанияПрофилей.Добавить(ОписаниеПрофиля);

Доступность

Сервер, Толстый клиент, Внешнее соединение