Подключает компоненту, выполненную по технологии Native API и COM, в асинхронном режиме. Компонента должна храниться в макете конфигурации в виде ZIP-архива. Для веб-клиента предлагается диалог, подсказывающий пользователю действия по установке.

Синтаксис

Процедура ПодключитьКомпонентуИзМакета(Оповещение, Идентификатор, ПолноеИмяМакета,
ПараметрыПодключения = Неопределено) Экспорт

Параметры

• Оповещение — ОписаниеОповещения - описание оповещения о подключении со следующими параметрами:
  • Результат - Структура - результат подключения компоненты: ** Подключено - Булево - признак подключения. ** ПодключаемыйМодуль - ОбъектВнешнейКомпоненты - экземпляр объекта внешней компоненты;
  • ФиксированноеСоответствие из КлючИЗначение - экземпляры объектов внешней компоненты, указанные в ПараметрыПодключения.ИдентификаторыСозданияОбъектов: *** Ключ - Строка - идентификатор внешней компоненты; *** Значение - ОбъектВнешнейКомпоненты - экземпляр объекта. ** ОписаниеОшибки - Строка - краткое описание ошибки. При отмене пользователем пустая строка.
  • ДополнительныеПараметры - Структура - значение, которое было указано при создании объекта ОписаниеОповещения.
• Идентификатор — Строка - идентификатор объекта внешней компоненты.
• ПолноеИмяМакета — Строка - полное имя макета, используемое как местоположение компоненты.
• ПараметрыПодключения — Структура
  • Неопределено - см. функцию ПараметрыПодключенияКомпоненты.

Пример вызова

Оповещение = Новый ОписаниеОповещения("ПодключитьКомпонентуЗавершение", ЭтотОбъект);
ПараметрыПодключения = ОбщегоНазначенияКлиент.ПараметрыПодключенияКомпоненты();
ПараметрыПодключения.ТекстПояснения = НСтр("ru = 'Для оформления заявления на выпуск сертификата требуется
                                           |внешняя компонента ""Криптография (CryptS)"".'");
ОбщегоНазначенияКлиент.ПодключитьКомпонентуИзМакета(Оповещение, 
    "CryptS",
    "Обработка.ЗаявлениеНаВыпускНовогоКвалифицированногоСертификата.Макет.КомпонентаОбмена",
    ПараметрыПодключения);
&НаКлиенте
Процедура ПодключитьКомпонентуЗавершение(Результат, ДополнительныеПараметры) Экспорт
    ПодключаемыйМодуль = Неопределено;
    Если Результат.Подключено Тогда 
        ПодключаемыйМодуль = Результат.ПодключаемыйМодуль;
    Иначе
        Если Не ПустаяСтрока(Результат.ОписаниеОшибки) Тогда
            ПоказатьПредупреждение(, Результат.ОписаниеОшибки);
        КонецЕсли;
    КонецЕсли;
    Если ПодключаемыйМодуль <> Неопределено Тогда 
        // ПодключаемыйМодуль содержит созданный экземпляр подключенной компоненты.
    КонецЕсли;
    ПодключаемыйМодуль = Неопределено;
КонецПроцедуры

Доступность

Тонкий клиент, Толстый клиент